~roshless/PKGBUILDs

ref: fa18ceeacca111ecfa3c69686028bc1f4d7433ff PKGBUILDs/kineto/PKGBUILD -rw-r--r-- 762 bytes
fa18ceeaRoshless upgpkg: gmni-git r146.b46b312-1 7 months ago
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
# Maintainer: Roshless <pkg@roshless.com>

pkgname=kineto-git
pkgver=r6.1074d43
pkgrel=1
pkgdesc='An HTTP to Gemini proxy'
url='https://git.sr.ht/~sircmpwn/kineto'
arch=('any')
license=('GPL')
makedepends=('git' 'go')
source=("kineto-git::git+https://git.sr.ht/~sircmpwn/kineto")

pkgver() {
    cd $pkgname
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd $pkgname
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
    go build -o kineto .
}

package() {
    cd $pkgname
    install -Dm755 kineto -t "$pkgdir/usr/bin/"
}

md5sums=('SKIP')